/* $Id$ */
/*============================================================================*
 |                 Copyright (c) 2011 Applaud Solutions UK Ltd                |
 |                             All rights reserved                            |
 *===========================================================================*/

SET VERIFY OFF
SET FEEDBACK OFF
SET ESCAPE '\'
WHENEVER OSERROR  EXIT FAILURE ROLLBACK
WHENEVER SQLERROR EXIT FAILURE ROLLBACK

DECLARE

  --
  -- Local constants and variables
  --
  e_no_bg_id          EXCEPTION;
  e_bg_not_exists     EXCEPTION;
  e_ff_type_not_found EXCEPTION;
  l_BG_ID   CONSTANT  NUMBER        := to_number('&1');
  l_USER_ID CONSTANT  NUMBER        := to_number('&2');
  l_START   CONSTANT  DATE          := to_date('1900-01-01','YYYY-MM-DD');
  l_END     CONSTANT  DATE          := xxas_util_pkg.eot;
  l_FF_NAME CONSTANT  VARCHAR2(80)  := 'XXAS_ORG_VIEW_POS_FACES';
  l_FF_DESC CONSTANT  VARCHAR2(240) := 'Position Faces Organization Chart View';
  l_FF_TYPE CONSTANT  varchar2(30)  := 'Applaud Assignment';
  l_formula_text      LONG;
  l_formula_type_id   NUMBER;
  l_ff_id             NUMBER;
  l_bg_exists         VARCHAR2(1);

  --
  -- Tests if the Business Group already exists
  --
  CURSOR csr_bg_exists IS
  SELECT 'Y'
  FROM   per_business_groups_perf bg
  WHERE  bg.business_group_id = l_BG_ID;

  --
  -- Gets the FF Id
  --
  CURSOR csr_ff_id IS
  SELECT ff.formula_id
  FROM   ff_formulas_f ff
  WHERE  ff.business_group_id = l_BG_ID
  AND    ff.formula_name = l_FF_NAME;

  --
  -- Gets the Formula Type Id
  --
  CURSOR csr_ff_type IS
  SELECT fft.formula_type_id
  FROM   ff_formula_types fft
  WHERE  fft.formula_type_name = l_FF_TYPE;

BEGIN

  --
  -- Check that the Business Group Id was passed in
  --
  IF l_BG_ID IS NULL THEN
    RAISE e_no_bg_id;
  END IF;

  --
  -- Check the Business Group exists
  --
  OPEN  csr_bg_exists;
  FETCH csr_bg_exists INTO l_bg_exists;
  CLOSE csr_bg_exists;

  IF l_bg_exists IS NULL THEN
    RAISE e_bg_not_exists;
  END IF;

  --
  -- Fetch the Fast Formula Id
  --
  OPEN  csr_ff_id;
  FETCH csr_ff_id INTO l_ff_id;
  CLOSE csr_ff_id;

  --
  -- Get the Formula Type; error if it cannot be found
  --
  OPEN  csr_ff_type;
  FETCH csr_ff_type INTO l_formula_type_id;
  CLOSE csr_ff_type;

  IF l_formula_type_id IS NULL THEN
    RAISE e_ff_type_not_found;
  END IF;

  --
  -- Set the Formula Text
  --
  l_formula_text := '
/*==============================================================================

Formula Name: XXAS_ORG_VIEW_POS_FACES
Formula Type: Applaud Assignment
Description:  Position Faces Organization Chart View

==============================================================================*/

  ALIAS PER_KNOWN_AS   AS Known_As
  ALIAS PER_FIRST_NAME AS First_Name
  ALIAS PER_LAST_NAME  AS Last_Name

  DEFAULT FOR PER_KNOWN_AS   IS ''Unknown''
  DEFAULT FOR PER_FIRST_NAME IS ''Unknown''
  DEFAULT FOR PER_LAST_NAME  IS ''Unknown''

  /* Constants */
  UNKNOWN = ''Unknown''

  /* Default assignment information */
  Status           = UNKNOWN
  FTE              = UNKNOWN
  Job_Title        = UNKNOWN
  Worker_Type      = UNKNOWN
  Job_Name         = UNKNOWN
  Position_Name    = UNKNOWN
  Department       = UNKNOWN
  Service          = UNKNOWN
  Location         = UNKNOWN
  Location_Address = UNKNOWN
  Latitude         = 0
  Longtitude       = 0

  /* Show this face. If you wish to hide certain people from the faces view, simply
     set this to ''No'' based on whatever condition you want that hides them. For example:
       If Last_Name = ''Smith'' Then
         (Show = ''No'') */
  Show = ''Yes''

  /* Set the person''s name as the label.  The label is the text that appears below the
     face. */
  Label = Last_Name + '', ''
  If Known_As was not defaulted then
      (Label = Label + Known_As)
  Else
      (Label = Label + First_Name)

  /* Retrieve assignment information from the assignment FF */
  result = xxas_get_assignment_details
             (Status, FTE, Job_Title, Worker_Type, Job_Name, Position_Name, Department
             ,Service, Location, Location_Address, Latitude, Longtitude)

  /* Set additional info to the assignment''s job title. Additional info
     appears as tooltip text when you hover over the face. */
  Additional_Info = Job_Title

  /* Set the URL and how it opens. URL can be set to a normal URL, such as to a
     function like Talent Profile.  When you click on a face that URL will open.
     New_Tab_or_Window (Y or N) determines how it opens: whether it opens in the
     same tab/window or whether it opens in a new tab/window.  Whether it''s a tab
     or a window is up to the browser and isn''t something that can be controlled.

     The URL ''org:drilldown'' is a special URL that will drilldown into the selected
     face to show the person view. With this special URL, New_Tab_or_Window isn''t
     relevant; it''s just set here for consistency. */
  Url = ''org:drilldown''
  New_Tab_or_Window = ''Y''

  RETURN Show, Label, Additional_Info, Url, New_Tab_or_Window
      /* Node_XML, Title_XML - not set because Faces views cannot be exported. */

';


  BEGIN

    IF l_ff_id IS NULL THEN
      --
      -- Create the Fast Formula
      --
      INSERT INTO ff_formulas_f
        (formula_id
        ,effective_start_date
        ,effective_end_date
        ,business_group_id
        ,formula_type_id
        ,formula_name
        ,description
        ,formula_text)
      VALUES
        (ff_formulas_s.nextval
        ,l_START
        ,l_END
        ,l_BG_ID
        ,l_formula_type_id
        ,l_FF_NAME
        ,l_FF_DESC
        ,l_formula_text);

    ELSE
      --
      -- Update the existing Fast Formula text
      -- (if it has multiple date-track versions the text of
      -- all versions is updated).
      --
      UPDATE ff_formulas_f
      SET    formula_text = l_formula_text
            ,description  = l_FF_DESC
      WHERE  formula_id = l_ff_id;

    END IF;

    COMMIT;

    EXCEPTION
      WHEN others THEN
        ROLLBACK;
        RAISE;
    END;

    --
    -- Compile the Fast Formula
    --
    xxas_util_pkg.compile_ff
      (p_user_id => l_USER_ID
      ,p_ff_type => l_FF_TYPE
      ,p_ff_name => l_FF_NAME);

EXCEPTION

  WHEN e_no_bg_id THEN
    RAISE no_data_found;

  WHEN e_bg_not_exists THEN
    RAISE no_data_found;

  WHEN e_ff_type_not_found THEN
    RAISE no_data_found;

END;
/
COMMIT;
EXIT;
